YADOT-WOLF カジノ内では所持金が所持メダルに変わる

ＷＯＬＦＲＰＧエディター(ウディタ)／演出・システム【サイトトップへ戻る】
■カジノ内では所持金が所持メダルに変わる
（更新：2024/05/12）

カジノに入った時に、所持金を所持メダルに変える処理を設定します。

通常時		カジノ内

ショートカット

■アイテム欄でメダルの所持数が確認できるようにする

■カジノ内でセーブが出来る場合

　　
■設定内容の確認

今回は所持金を所持メダルに変える処理やメダルをアイテムに交換する処理の設定方法を紹介します。

カジノにあるスロットやルーレットなどの設定方法はありませんので、
欲しい方はウディタの公式サイトにあるコモン素材などをご利用ください。

メダルの所持枚数は通常変数[1:メダル枚数]に保存します。

そしてカジノに入る時に通常変数[1:メダル枚数]と所持金を入れ替えて、
カジノ内では所持金にメダルの所持枚数を保存し、通常変数[1:メダル枚数]には所持金を保存とします。

このように所持金と所持メダルを入れ替える事で、カジノ内のメダルの増減処理は通常の所持金の処理で行う事ができます。

メニュー画面の左下表示の表示は、カジノ内では所持メダルの表示に変えます。

メダルとアイテムを交換する処理には、お店の処理が使えます。

なお、アイテムの交換所では、アイテムに交換できるメダル枚数を表示する必要があるため、
今回の設定ではユーザーＤＢ[2:アイテム][3:武器][4:防具]のそれぞれに項目[メダル交換枚数]を新設し、
各アイテム・武器・防具の交換枚数が設定できるようにします。

例えば「魔力の水」の場合は、販売価格は「120ゴールド」ですが、メダルの交換枚数は「15枚」と言った感じです。

メダルを購入する処理も、お店の処理を使います。

但しカジノ内の所持金は所持メダルになっているため、このメダルの購入の際は一時的に元の所持金に戻します。

所持金の単位はユーザーＤＢ[15:用語設定]の項目[18:[ｽﾃｰﾀｽ]お金の単位]で設定しますが、
カジノ内では「枚」、それ以外では「ゴールド」の表記にするため、
カジノを出入りする時には「変数呼び出し値（1015000018）」を使って、お金の単位を変えるように設定します。

この「変数呼び出し値」を使ったユーザーＤＢの書き換えは、一時的な設定変更になるため、
カジノ内でセーブして、そのセーブデータをロードすると、元の「ゴールド」に戻ります。

もしもカジノ内でセーブが出来るようにする場合は、
ロード後に「変数呼び出し値」を使って再びお金の単位を「枚」に変える必要があります。

なお、カジノの場合は、セーブしてうまくいかなかったらロードしてやり直すプレイヤーがいるため、
カジノ内のマップではセーブが出来ないようにした方が良いかもしれません。

イベントコードは通常変数[1]やユーザーＤＢ[2:アイテム]のデータＩＤ[50～54]の設定になっているため、
異なる変数番号やデータＩＤを使用する場合は、イベントコードの貼り付けた後に修正する必要があります。

▲トップへ戻る▲

　　
■データベースの準備

データベースの準備を行います。

追加する変数や項目の番号は、未使用の番号を割り当ててください。

▼システムＤＢ

システムＤＢ[14:通常変数名]にメダルの所持枚数を保存する通常変数[メダル枚数]を設定してください。
使用する変数番号は自由に選択してください。
通常変数ではなく、予備変数を使っても問題ありません。

▼ユーザーＤＢ

ユーザーＤＢ[2:アイテム]に項目[メダル交換枚数]を新設してください。

同様の設定はユーザーＤＢ[3:武器][4:防具]にも行ってください。

アイテム・武器・防具ごとに、メダル交換枚数を設定してください。

メダルを購入する時に使う「メダル10枚」などのアイテムを準備してください。
設定する内容は「アイテム名」「説明文」「販売価格」のみで良いです。

▲トップへ戻る▲

　　
■カジノを出入りする時の処理

カジノに入る時には所持金を所持メダルに変え、
カジノから出る時には所持メダルを所持金に変えます。

カジノ内の通常変数[1:メダル枚数]には所持金が保存されています。
そのため、もしもスロットなどでメダルの増減処理がある場合は、
通常変数[1:メダル枚数]ではなく所持金の方を増減してください。

以下のイベントは、カジノのマップへ入る時、
または出る時の場所移動イベントの中に設定してください。

▼カジノに入る時

「1015000018」は「データを呼ばない」で設定してください。

【文字列操作】は「代入先を変数で指定」で設定してください。

▼カジノから出る時

▲トップへ戻る▲

　　
■メダルを購入

所持金でメダルを購入する処理を設定します。

このメダルの購入処理は、お店の処理を使って行います。

カジノ内の所持金はメダルの枚数になっているので、このメダルの購入の際は、一時的に元の所持金に戻してください。

【イベントコード表示】

■DB読込(可変)：このEvのSelf0 = 可変DB[ 6 : 0 : 0 ] (パーティー情報 : メイン設定 : 所持金)
■可変DB書込：DB[ 6 : 0 : 0 ] (パーティー情報 : メイン設定 : 所持金) = V1[メダル枚数]
■変数操作: V1[メダル枚数] = このEvのSelf0 + 0
■変数操作: このEvのSelf0 = 1015000018 + 0
■文字列操作：V[このEvのSelf0] = "ゴールド"
■イベントの挿入[名]： ["【1】お店初期化"] <コモンEv 33>
■イベントの挿入[名]： ["【2】お店商品の追加"] <コモンEv 34> / 1:ｱｲﾃﾑ[A] / 50:メダル10枚 / -1:<なし> / -1:<なし>
■イベントの挿入[名]： ["【2】お店商品の追加"] <コモンEv 34> / 1:ｱｲﾃﾑ[A] / 51:メダル100枚 / -1:<なし> / -1:<なし>
■イベントの挿入[名]： ["【2】お店商品の追加"] <コモンEv 34> / 1:ｱｲﾃﾑ[A] / 52:メダル1000枚 / -1:<なし> / -1:<なし>
■イベントの挿入[名]： ["【3】お店処理実行"] <コモンEv 35> / 2:買いのみ
■DB読込(可変)：このEvのSelf0 = 可変DB[ 6 : 0 : 0 ] (パーティー情報 : メイン設定 : 所持金)
■可変DB書込：DB[ 6 : 0 : 0 ] (パーティー情報 : メイン設定 : 所持金) = V1[メダル枚数]
■変数操作: V1[メダル枚数] = このEvのSelf0 + 0
■変数操作: このEvのSelf0 = 1015000018 + 0
■文字列操作：V[このEvのSelf0] = "枚"
■イベントの挿入[名]：このEvのSelf0 = ["▲アイテム所持数取得"] <コモンEv 17> / 50:メダル10枚
■イベントの挿入[名]： ["○アイテム増減"] <コモンEv 0> / 50:メダル10枚 / -99 / 0:なし
■変数操作: 可変DB[6:0:0](所持金) += このEvのSelf0 * 10
■イベントの挿入[名]：このEvのSelf0 = ["▲アイテム所持数取得"] <コモンEv 17> / 51:メダル100枚
■イベントの挿入[名]： ["○アイテム増減"] <コモンEv 0> / 51:メダル100枚 / -99 / 0:なし
■変数操作: 可変DB[6:0:0](所持金) += このEvのSelf0 * 100
■イベントの挿入[名]：このEvのSelf0 = ["▲アイテム所持数取得"] <コモンEv 17> / 52:メダル1000枚
■イベントの挿入[名]： ["○アイテム増減"] <コモンEv 0> / 52:メダル1000枚 / -99 / 0:なし
■変数操作: 可変DB[6:0:0](所持金) += このEvのSelf0 * 1000

▲トップへ戻る▲

　　
■アイテムの交換所

メダルとアイテムを交換する処理を設定します。

この処理もお店の処理を使って行います。

▼コモンイベント[083:X[移]お店商品追加]を改造

お店の処理で購入できるアイテムの表示には万能ウィンドウを使っています。

万能ウィンドウは可変ＤＢ[19:万能ｳｨﾝﾄﾞｳ一時DB]に登録された情報を基に一覧を表示しており、
コモンイベント[083:X[移]お店商品追加]では販売するアイテムを可変ＤＢ[19:万能ｳｨﾝﾄﾞｳ一時DB]に登録しています。

今回の改造では、お金の単位が「枚」になっている時のアイテム登録では、
販売価格では無く、メダル交換枚数が可変ＤＢ[19:万能ｳｨﾝﾄﾞｳ一時DB]に登録されるように改造します。

以下の黄色のイベントコマンドを追加してください。

【イベントコード表示】【コモン出力ファイル】

■コモンイベント[083:X[移]お店商品追加]

▼ ―――――――――――――――――――――――――――――――――――
▼ 【処理の内容】
▼ お店の商品を追加します。武器・防具なら装備可能キャラも計算します。
▼ ―――――――――――――――――――――――――――――――――――
■DB読込(ﾕｰｻﾞ)： CSelf5 = ﾕｰｻﾞDB[ 15 : 0 : 18 ] (用語設定 : 用語基本設定 : [ｽﾃｰﾀｽ]お金の単位)
■変数操作: CSelf15[商品コード[番号]] = CSelf0[商品コード] + 0
■DB読込(可変)： CSelf16[次格納先] = 可変DB[ 基本ｼｽﾃﾑ用変数 : [お店]ｱｲﾃﾑ登録個数 : 0 ] (18 : 93 : 数値)
■条件分岐(変数): 【1】 CSelf0[商品コード] が 10000 以上
-◇分岐：【1】 [ CSelf0[商品コード] が 10000 以上 ]の場合↓
|■条件分岐(変数): 【1】 CSelf0[商品コード] が 19999 以下
　　　　　　　　　【2】 CSelf0[商品コード] が 29999 以下
　　　　　　　　　【3】 CSelf0[商品コード] が 39999 以下
|-◇分岐：【1】 [ CSelf0[商品コード] が 19999 以下 ]の場合↓
||▼ アイテムの場合
||■変数操作: CSelf15[商品コード[番号]] %= 10000 + 0
||▼
||■DB読込(可変)： CSelf19[所持数] = 可変DB[ ┣所持アイテム個数 : CSelf15[商品コード[番号]] : 所持個数 ] (7 : - : 0)
||■DB読込(ﾕｰｻﾞ)： CSelf18[価格] = ﾕｰｻﾞDB[ アイテム : CSelf15[商品コード[番号]] : 販売価格 [0=売れない] ] (2 : - : 19)
||■条件分岐(文字): 【1】 CSelf5が "枚" と同じ
||-◇分岐：【1】 [ CSelf5 "枚" と同じ ]の場合↓
|||■DB読込(ﾕｰｻﾞ)： CSelf18[価格] = ﾕｰｻﾞDB[ アイテム : CSelf15[商品コード[番号]] : メダル交換枚数 ] (2 : - : 21)
|||■
||◇分岐終了◇
||■DB読込(ﾕｰｻﾞ)： CSelf9[商品名] = ﾕｰｻﾞDB[ アイテム : CSelf15[商品コード[番号]] : アイテム名 ] (2 : - : 0)
||■DB読込(ﾕｰｻﾞ)： CSelf8[商品説明] = ﾕｰｻﾞDB[ アイテム : CSelf15[商品コード[番号]] : 説明文[2行まで可] ] (2 : - : 1)
||▼
||■可変DB書込：DB[ × お店一時処理用 : CSelf16[次格納先] : 販売アイテムコード ] (16 : - : 1) = CSelf0[商品コード]
||■可変DB書込：DB[ × お店一時処理用 : CSelf16[次格納先] : 販売アイテム名 ] (16 : - : 0) = CSelf9[商品名]
||■可変DB書込：DB[ × お店一時処理用 : CSelf16[次格納先] : 説明文 ] (16 : - : 5) = CSelf8[商品説明]
||■可変DB書込：DB[ × お店一時処理用 : CSelf16[次格納先] : 所持数 ] (16 : - : 3) = CSelf19[所持数]
||■可変DB書込：DB[ × お店一時処理用 : CSelf16[次格納先] : 価格 ] (16 : - : 2) = CSelf18[価格]
||▼
||■可変DB書込：DB[ 基本ｼｽﾃﾑ用変数 : 93 : 0 ] (18 : [お店]ｱｲﾃﾑ登録個数 : 数値) += 1
||■
|-◇分岐：【2】 [ CSelf0[商品コード] が 29999 以下 ]の場合↓
||▼ 武器の場合
||■変数操作: CSelf15[商品コード[番号]] %= 20000 + 0
||▼
||■DB読込(可変)： CSelf19[所持数] = 可変DB[ ┣所持武器個数 : CSelf15[商品コード[番号]] : 所持個数 ] (8 : - : 0)
||■DB読込(ﾕｰｻﾞ)： CSelf18[価格] = ﾕｰｻﾞDB[ 武器 : CSelf15[商品コード[番号]] : 販売価格 [0=売れない] ] (3 : - : 17)
||■条件分岐(文字): 【1】 CSelf5が "枚" と同じ
||-◇分岐：【1】 [ CSelf5 "枚" と同じ ]の場合↓
|||■DB読込(ﾕｰｻﾞ)： CSelf18[価格] = ﾕｰｻﾞDB[ 武器 : CSelf15[商品コード[番号]] : メダル交換枚数 ] (3 : - : 30 )
|||■
||◇分岐終了◇
||■DB読込(ﾕｰｻﾞ)： CSelf9[商品名] = ﾕｰｻﾞDB[ 武器 : CSelf15[商品コード[番号]] : 武器の名前 ] (3 : - : 0)
||■DB読込(ﾕｰｻﾞ)： CSelf8[商品説明] = ﾕｰｻﾞDB[ 武器 : CSelf15[商品コード[番号]] : 武器の説明[2行まで可] ] (3 : - : 1)
||▼
||■可変DB書込：DB[ × お店一時処理用 : CSelf16[次格納先] : 販売アイテムコード ] (16 : - : 1) = CSelf0[商品コード]
||■可変DB書込：DB[ × お店一時処理用 : CSelf16[次格納先] : 販売アイテム名 ] (16 : - : 0) = CSelf9[商品名]
||■可変DB書込：DB[ × お店一時処理用 : CSelf16[次格納先] : 説明文 ] (16 : - : 5) = CSelf8[商品説明]
||■可変DB書込：DB[ × お店一時処理用 : CSelf16[次格納先] : 所持数 ] (16 : - : 3) = CSelf19[所持数]
||■可変DB書込：DB[ × お店一時処理用 : CSelf16[次格納先] : 価格 ] (16 : - : 2) = CSelf18[価格]
||▼
||■可変DB書込：DB[ 基本ｼｽﾃﾑ用変数 : 93 : 0 ] (18 : [お店]ｱｲﾃﾑ登録個数 : 数値) += 1
||■
|-◇分岐：【3】 [ CSelf0[商品コード] が 39999 以下 ]の場合↓
||▼ 防具の場合
||■変数操作: CSelf15[商品コード[番号]] %= 30000 + 0
||▼
||■DB読込(可変)： CSelf19[所持数] = 可変DB[ ┗所持防具個数 : CSelf15[商品コード[番号]] : 所持個数 ] (9 : - : 0)
||■DB読込(ﾕｰｻﾞ)： CSelf18[価格] = ﾕｰｻﾞDB[ 防具 : CSelf15[商品コード[番号]] : 販売価格 [0=売れない] ] (4 : - : 18)
||■条件分岐(文字): 【1】 CSelf5が "枚" と同じ
||-◇分岐：【1】 [ CSelf5 "枚" と同じ ]の場合↓
|||■DB読込(ﾕｰｻﾞ)： CSelf18[価格] = ﾕｰｻﾞDB[ 防具 : CSelf15[商品コード[番号]] : メダル交換枚数 ] (4 : - : 38 )
|||■
||◇分岐終了◇
||■DB読込(ﾕｰｻﾞ)： CSelf9[商品名] = ﾕｰｻﾞDB[ 防具 : CSelf15[商品コード[番号]] : 防具の名前 ] (4 : - : 0)
||■DB読込(ﾕｰｻﾞ)： CSelf8[商品説明] = ﾕｰｻﾞDB[ 防具 : CSelf15[商品コード[番号]] : 防具の説明[2行まで可] ] (4 : - : 1)
||▼
||■可変DB書込：DB[ × お店一時処理用 : CSelf16[次格納先] : 販売アイテムコード ] (16 : - : 1) = CSelf0[商品コード]
||■可変DB書込：DB[ × お店一時処理用 : CSelf16[次格納先] : 販売アイテム名 ] (16 : - : 0) = CSelf9[商品名]
||■可変DB書込：DB[ × お店一時処理用 : CSelf16[次格納先] : 説明文 ] (16 : - : 5) = CSelf8[商品説明]
||■可変DB書込：DB[ × お店一時処理用 : CSelf16[次格納先] : 所持数 ] (16 : - : 3) = CSelf19[所持数]
||■可変DB書込：DB[ × お店一時処理用 : CSelf16[次格納先] : 価格 ] (16 : - : 2) = CSelf18[価格]
||▼
||■可変DB書込：DB[ 基本ｼｽﾃﾑ用変数 : 93 : 0 ] (18 : [お店]ｱｲﾃﾑ登録個数 : 数値) += 1
||■
|◇分岐終了◇
|■
◇分岐終了◇
■

▼コモンイベント[085:X[移]┣ お店　描画]を改造

このコモンイベント[085:X[移]┣ お店　描画]では、
お店の画面の右上に表示されるウィンドウの「所持金」を「所持メダル」に変えます。

以下の黄色のイベントコマンドを追加してください。

【イベントコード表示(全て)】【イベントコード表示(315行目の追加分のみ)】【コモン出力ファイル】

■コモンイベント[085:X[移]┣ お店　描画]

▼ ―――――――――――――――――――――――――――――――――――
▼ 【処理の内容】
▼ - お店の初期描画
▼ - カーソル位置の更新
▼ ―――――――――――――――――――――――――――――――――――
▼ 【ピクチャ】
▼ 基本ピクチャ＋0 ＝下地
▼ 基本ピクチャ＋1 ＝上部買う・売るウィンドウ
▼ 基本ピクチャ＋2 ＝買う用カーソル
▼ 基本ピクチャ＋3 ＝売る用カーソル
▼ 基本ピクチャ＋4 ＝買う
▼ 基本ピクチャ＋5 ＝売る
▼
▼ 基本ピクチャ＋10～32 ＝
▼ 10：所持金ウィンドウ 11：所持金
▼ 20：所持数ウィンドウ 21：所持数
▼ 30：装備可能ウィンドウ 31：装備可能状態文字列
▼ ―――――――――――――――――――――――――――――――――――
▼ ■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■
▼ パラメータ設定
▼ ■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■
▼ 固定値を設定
■変数操作: CSelf20[基本ピクチャ番号] = 12000 + 0
▼ 外部パラメータ読み込み
■DB読込(可変)：CSelf17[最小フォントサイズ] = 可変DB[ 基本ｼｽﾃﾑ用変数 : 7 : 0 ](18 : システム最小フォントサイズ : 数値)
■DB読込(可変)：CSelf18[ミニフォントサイズ] = 可変DB[ 基本ｼｽﾃﾑ用変数 : 6 : 0 ](18 : システムミニフォントサイズ : 数値)
■DB読込(可変)：CSelf19[基本フォントサイズ] = 可変DB[ 基本ｼｽﾃﾑ用変数 : 5 : 0 ](18 : システム基本フォントサイズ : 数値)
■DB読込(ﾕｰｻﾞ)：CSelf8[ウィンドウ画像ファイル]=ﾕｰｻﾞDB[ 画像/音声設定:0:ウィンドウ画像ファイル](16:画像/音声基本設定:0)
■DB読込(ﾕｰｻﾞ)：CSelf9[カーソル画像ファイル]=ﾕｰｻﾞDB[ 画像/音声設定 : 0 : カーソル画像ファイル](16:画像/音声基本設定:1)
■DB読込(ﾕｰｻﾞ)：CSelf27[装備欄縦項目数] = ﾕｰｻﾞDB[ システム設定 : 0 : 装備可能欄数](17 : システム基本設定 : 22)
▼ Ver2.20 座標倍率を縦横別に修正
■DB読込(可変)：CSelf88[座標倍率X[x10]] = 可変DB[ 基本ｼｽﾃﾑ用変数 : 97 : 0 ] (18 : 座標倍率Ｘ[x10] : 数値)
■DB読込(可変)：CSelf89[座標倍率Y[x10]] = 可変DB[ 基本ｼｽﾃﾑ用変数 : 98 : 0 ] (18 : 座標倍率Ｙ[x10] : 数値)
■変数操作: CSelf54[色指定R] = 60 + 0
■変数操作: CSelf55[色指定G] = 60 + 0
■変数操作: CSelf56[色指定B] = 100 + 0
▼ 座標設定（左上）
■変数操作: CSelf22[上部欄表示X] = 0 + 0
■変数操作: CSelf23[上部欄表示Y] = 0 + 0
■変数操作: CSelf24[上部欄横サイズ] = 180 + 0
■変数操作: CSelf25[上部欄縦サイズ] = 20 + 0
■変数操作: CSelf46[上部欄 [購入]シフト量] = 60 + 0
■変数操作: CSelf47[上部欄 [売却]シフト量] = 120 + 0
■変数操作: CSelf48[上部欄カーソル横サイズ] = 60 + 0
▼ お金欄座標設定
■変数操作: CSelf30[お金欄X] = 205 + 0
■変数操作: CSelf31[お金欄Y] = 5 + 0
■変数操作: CSelf32[お金欄横サイズ] = 110 + 0
■変数操作: CSelf33[お金欄縦サイズ] = 35 + 0
▼ 所持数座標設定
■変数操作: CSelf70[所持数欄表示X] = 205 + 0
■変数操作: CSelf71[所持数欄表示Y] = 40 + 0
■変数操作: CSelf72[所持数欄サイズX] = 110 + 0
■変数操作: CSelf73[所持数欄サイズY] = 27 + 0
▼ 装備状態欄座標設定
■DB読込(可変)： CSelf96[パーティ人数] = 可変DB[ 基本ｼｽﾃﾑ用変数 : 現在パーティー人数 : 0 ] (18 : 4 : 数値)
■変数操作: CSelf50[装備状態欄X] = 205 + 0
■変数操作: CSelf51[装備状態欄Y] = 73 + 0
■変数操作: CSelf52[装備状態欄横サイズ] = 110 + 0
■変数操作: CSelf53[装備状態欄縦サイズ] = 4 + 0
■変数操作: CSelf53[装備状態欄縦サイズ] *= CSelf96[パーティ人数] + 0
■変数操作: CSelf53[装備状態欄縦サイズ] += 15 + 0
■回数付きループ [ 1 ]回
|▼ 万能ウィンドウの座標
|■変数操作: CSelf75[万能ウィンドウ表示X] = 0 + 0
|■変数操作: CSelf76[万能ウィンドウ表示Y] = 20 + 0
|■変数操作: CSelf77[万能ウィンドウサイズX] = 200 + 0
|■変数操作: CSelf78[万能ウィンドウ表示Y] = 190 + 0
|■変数操作: CSelf79[万能ウィンドウ説明欄縦サイズ] = 28 + 0
|■変数操作: CSelf75[万能ウィンドウ表示X] *= CSelf88[座標倍率X[x10]] + 0
|■変数操作: CSelf76[万能ウィンドウ表示Y] *= CSelf89[座標倍率Y[x10]] + 0
|■変数操作: CSelf77[万能ウィンドウサイズX] *= CSelf88[座標倍率X[x10]] + 0
|■変数操作: CSelf78[万能ウィンドウ表示Y] *= CSelf89[座標倍率Y[x10]] + 0
|■変数操作: CSelf79[万能ウィンドウ説明欄縦サイズ] *= CSelf89[座標倍率Y[x10]] + 0
|■変数操作: CSelf75[万能ウィンドウ表示X]～CSelf79[万能ウィンドウ説明欄縦サイズ] /= 10 + 0
|▼ ここでセットしておく
|■可変DB書込：DB[基本ｼｽﾃﾑ用変数 : 9 : 0](18:万能ウィンドウ表示X:数値) = CSelf75[万能ウィンドウ表示X]
|■可変DB書込：DB[基本ｼｽﾃﾑ用変数 : 10 : 0](18:万能ウィンドウ表示Y:数値) = CSelf76[万能ウィンドウ表示Y]
|■可変DB書込：DB[基本ｼｽﾃﾑ用変数 : 11 : 0](18:万能ウィンドウ横サイズ:数値) = CSelf77[万能ウィンドウサイズX]
|■可変DB書込：DB[基本ｼｽﾃﾑ用変数 : 12 : 0](18:万能ウィンドウ縦サイズ:数値) = CSelf78[万能ウィンドウ表示Y]
|■可変DB書込：DB[基本ｼｽﾃﾑ用変数 : 13 : 0](18:万能ウィンドウ横項目数:数値) = 1
|■可変DB書込：DB[基本ｼｽﾃﾑ用変数 : 14 : 0](18:万能ウィンドウ縦項目数:数値) = 13
|■可変DB書込：DB[基本ｼｽﾃﾑ用変数 : 16 : 0](18:万能ウィンドウ説明欄縦サイズ:数値)=CSelf79[万能ウィンドウ説明欄縦サイズ]
|■
◇ループここまで◇◇
▼ 座標倍率補正をかける
■変数操作: CSelf22[上部欄表示X] *= CSelf88[座標倍率X[x10]] + 0
■変数操作: CSelf23[上部欄表示Y] *= CSelf89[座標倍率Y[x10]] + 0
■変数操作: CSelf24[上部欄横サイズ] *= CSelf88[座標倍率X[x10]] + 0
■変数操作: CSelf25[上部欄縦サイズ] *= CSelf89[座標倍率Y[x10]] + 0
■変数操作: CSelf22[上部欄表示X]～CSelf25[上部欄縦サイズ] /= 10 + 0
■変数操作: CSelf30[お金欄X] *= CSelf88[座標倍率X[x10]] + 0
■変数操作: CSelf31[お金欄Y] *= CSelf89[座標倍率Y[x10]] + 0
■変数操作: CSelf32[お金欄横サイズ] *= CSelf88[座標倍率X[x10]] + 0
■変数操作: CSelf33[お金欄縦サイズ] *= CSelf89[座標倍率Y[x10]] + 0
■変数操作: CSelf30[お金欄X]～CSelf33[お金欄縦サイズ] /= 10 + 0
■変数操作: CSelf46[上部欄 [購入]シフト量]～CSelf48[上部欄カーソル横サイズ] *= CSelf88[座標倍率X[x10]] + 0
■変数操作: CSelf46[上部欄 [購入]シフト量]～CSelf48[上部欄カーソル横サイズ] /= 10 + 0
■変数操作: CSelf50[装備状態欄X] *= CSelf88[座標倍率X[x10]] + 0
■変数操作: CSelf51[装備状態欄Y] *= CSelf89[座標倍率Y[x10]] + 0
■変数操作: CSelf52[装備状態欄横サイズ] *= CSelf88[座標倍率X[x10]] + 0
■変数操作: CSelf53[装備状態欄縦サイズ] *= CSelf89[座標倍率Y[x10]] + 0
■変数操作: CSelf50[装備状態欄X]～CSelf53[装備状態欄縦サイズ] /= 10 + 0
■変数操作: CSelf53[装備状態欄縦サイズ] += CSelf18[ミニフォントサイズ] * CSelf96[パーティ人数]
■変数操作: CSelf63[キャラ名位置Y] *= CSelf89[座標倍率Y[x10]] + 0
■変数操作: CSelf64[肩書き位置X] *= CSelf88[座標倍率X[x10]] + 0
■変数操作: CSelf65[肩書き位置Y] *= CSelf89[座標倍率Y[x10]] + 0
■変数操作: CSelf66[HP位置X] *= CSelf88[座標倍率X[x10]] + 0
■変数操作: CSelf67[HP位置Y] *= CSelf89[座標倍率Y[x10]] + 0
■変数操作: CSelf68[SP位置X] *= CSelf88[座標倍率X[x10]] + 0
■変数操作: CSelf69[SP位置Y] *= CSelf89[座標倍率Y[x10]] + 0
■変数操作: CSelf70[所持数欄表示X] *= CSelf88[座標倍率X[x10]] + 0
■変数操作: CSelf71[所持数欄表示Y] *= CSelf89[座標倍率Y[x10]] + 0
■変数操作: CSelf72[所持数欄サイズX] *= CSelf88[座標倍率X[x10]] + 0
■変数操作: CSelf73[所持数欄サイズY] *= CSelf89[座標倍率Y[x10]] + 0
■変数操作: CSelf63[キャラ名位置Y]～CSelf73[所持数欄サイズY] /= 10 + 0
■変数操作: CSelf80[全ゲージ太さ] *= CSelf89[座標倍率Y[x10]] + 0
■変数操作: CSelf81[HP・SPゲージ長] *= CSelf88[座標倍率X[x10]] + 0
■変数操作: CSelf80[全ゲージ太さ]～CSelf81[HP・SPゲージ長] /= 10 + 0
▼ 初期化
■変数操作: CSelf29[全更新フラグ] = 0 + 0
▼ ■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■
▼ ここから実処理開始
▼ ■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■
■条件分岐(変数): 【1】 CSelf0[処理モード] が 3 と同じ
-◇分岐：【1】 [ CSelf0[処理モード] が 3 と同じ ]の場合↓
|■イベントの挿入[名]： ["X[共]万能ｳｨﾝﾄﾞｳ描画処理"] <コモンEv 64> / 0:表示 / -1 / 2:最下部に横幅最大表示 / 0:なし
|■変数操作: CSelf0[処理モード] = 1 + 0
|■
◇分岐終了◇
▼ ■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■
■条件分岐(変数): 【1】 CSelf0[処理モード] が -1 と同じ
-◇分岐：【1】 [ CSelf0[処理モード] が -1 と同じ ]の場合↓
|▼ ■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■
|▼ 「消去」モード
|▼ ■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■
|▼ 下地だけは単体で消去
|■ﾋﾟｸﾁｬ[ﾃﾞｨﾚｲ内容ﾘｾｯﾄ]：CSelf20[基本ピクチャ番号]
|■ﾋﾟｸﾁｬ消去：CSelf20[基本ピクチャ番号] / 10(0)ﾌﾚｰﾑ
|▼ それ以外は右にスライド消去
|■変数操作: CSelf11[一時変数B] = CSelf20[基本ピクチャ番号] + 1
|■変数操作: CSelf21[一時ピクチャ番号] = CSelf20[基本ピクチャ番号] + 80
|■ﾋﾟｸﾁｬ[ﾃﾞｨﾚｲ内容ﾘｾｯﾄ]：CSelf11[一時変数B] ～ CSelf21[一時ピクチャ番号]
|■変数操作: CSelf10[一時変数A] = 120 * CSelf88[座標倍率X[x10]]
|■変数操作: CSelf10[一時変数A] /= 10 + 0
|■ﾋﾟｸﾁｬ移動：CSelf11[一時変数B] ～ CSelf21[一時ピクチャ番号] 相対X:CSelf10[一時変数A] Y:0 / 7(0)ﾌﾚｰﾑ /
　　　　　　　ﾊﾟﾀｰﾝ同値 / 透同値 / 表示形式:同値 / 角同値 / 拡同値 / ｶﾗｰ同値
|■ﾋﾟｸﾁｬ消去：CSelf11[一時変数B] ～ CSelf21[一時ピクチャ番号] / 0(7)ﾌﾚｰﾑ
|■イベントの挿入[名]： ["X[共]万能ｳｨﾝﾄﾞｳ描画処理"] <コモンEv 64>/-1:消去/-1/2:最下部に横幅最大表示/1:左上から展開
|■イベント処理中断
|■
◇分岐終了◇
■条件分岐(変数): 【1】 CSelf0[処理モード] が 0 以上
-◇分岐：【1】 [ CSelf0[処理モード] が 0 以上 ]の場合↓
|■条件分岐(変数): 【1】 CSelf0[処理モード] が 1 以下
|-◇分岐：【1】 [ CSelf0[処理モード] が 1 以下 ]の場合↓
||▼ ■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■
||▼ 「表示」モード
||▼ ■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■
||■変数操作: CSelf57[初期表示？(1=YES)] = 0 + 0
||■条件分岐(変数): 【1】 CSelf0[処理モード] が 0 と同じ
||-◇分岐：【1】 [ CSelf0[処理モード] が 0 と同じ ]の場合↓
|||▼ ●初期化モード
|||▼ 初期表示なら、1を格納（処理のオンオフ判定に使用）
|||■変数操作: CSelf57[初期表示？(1=YES)] = 1 + 0
|||▼ 万能ウィンドウ表示
|||■イベントの挿入[名]：["X[共]万能ｳｨﾝﾄﾞｳ描画処理"]<コモンEv 64>/0:表示/-1/2:最下部に横幅最大表示/1:左上から展開
|||■
||-◇上記以外
|||■
||◇分岐終了◇
||▼ 表示パラメータの取得
||■DB読込(可変)： CSelf95[所持金] = 可変DB[ パーティー情報 : 0 : 所持金 ] (6 : メイン設定 : 0)
||▼
||■回数付きループ [ CSelf57[初期表示？(1=YES)] ]回
|||▼ 下地
|||■変数操作: CSelf21[一時ピクチャ番号] = CSelf20[基本ピクチャ番号] + 0
|||■ﾋﾟｸﾁｬ[ﾃﾞｨﾚｲ内容ﾘｾｯﾄ]：CSelf21[一時ピクチャ番号]
|||■変数操作: CSelf10[一時変数A] = CSelf88[座標倍率X[x10]] * 32
|||■変数操作: CSelf11[一時変数B] = CSelf89[座標倍率Y[x10]] * 24
|||■ﾋﾟｸﾁｬ表示：CSelf21[一時ピクチャ番号] [左上]ｳｨﾝﾄﾞｳ「<GRADY-779-111>」
　　　　　　　　ｻｲｽﾞ[CSelf10[一時変数A],CSelf11[一時変数B]] X:0 Y:0 / 10(0)ﾌﾚｰﾑ /
　　　　　　　　ﾊﾟﾀｰﾝ 1 / 透 255 / 乗算 / 角 0 / 拡 100％ / ｶﾗｰ R[100] G[100] B[100]
|||■
||◇ループここまで◇◇
||▼
||■回数付きループ [ 1 ]回
|||■チェックポイント■■■■■■■■■■■■■■■■■■■■■■■■
|||▼ 買う、売る欄を表示
|||■回数付きループ [ CSelf57[初期表示？(1=YES)] ]回
||||■変数操作: CSelf21[一時ピクチャ番号] = CSelf20[基本ピクチャ番号] + 1
||||■ﾋﾟｸﾁｬ[ﾃﾞｨﾚｲ内容ﾘｾｯﾄ]：CSelf21[一時ピクチャ番号]
||||■ﾋﾟｸﾁｬ表示：CSelf21[一時ピクチャ番号] [左上]ｳｨﾝﾄﾞｳ(CSelf8[ウィンドウ画像ファイル])
　　　　　　　　ｻｲｽﾞ[CSelf24[上部欄横サイズ],CSelf25[上部欄縦サイズ]] X:CSelf22[上部欄表示X] Y:CSelf23[上部欄表示Y]/
　　　　　　　　 0(0)ﾌﾚｰﾑ / ﾊﾟﾀｰﾝ 1 / 透 255 / 通常 / 角 0 / 拡 100％ / ｶﾗｰ R[100] G[100] B[100]
||||■回数付きループ [ 1 ]回
|||||▼ ここで表示エフェクト（「移動」コマンドで実現している）
|||||▼ 初期位置をシフト
|||||■変数操作: CSelf41[一時項目表示X] = CSelf22[上部欄表示X] + 0
|||||■変数操作: CSelf42[一時項目表示Y] = CSelf23[上部欄表示Y] + 0
|||||■変数操作: CSelf44[一時項目表示X2] = CSelf22[上部欄表示X] - CSelf24[上部欄横サイズ]
|||||■変数操作: CSelf45[一時項目表示Y2] = CSelf42[一時項目表示Y] + 0
|||||■ﾋﾟｸﾁｬ[ﾃﾞｨﾚｲ内容ﾘｾｯﾄ]：CSelf21[一時ピクチャ番号]
|||||■ﾋﾟｸﾁｬ移動：CSelf21[一時ピクチャ番号] X:CSelf44[一時項目表示X2] Y:CSelf45[一時項目表示Y2] / 0(0)ﾌﾚｰﾑ /
　　　　　　　　　ﾊﾟﾀｰﾝ 1 / 透同値 / 表示形式:同値 / 角同値 / 拡同値 / ｶﾗｰ同値
|||||▼ 慣性移動
|||||■ﾋﾟｸﾁｬ移動：CSelf21[一時ピクチャ番号] X:CSelf41[一時項目表示X] Y:CSelf42[一時項目表示Y] / 5(0)ﾌﾚｰﾑ /
　　　　　　　　　ﾊﾟﾀｰﾝ 1 / 透同値 / 表示形式:同値 / 角同値 / 拡同値 / ｶﾗｰ同値
|||||■ﾋﾟｸﾁｬ移動：CSelf21[一時ピクチャ番号] X:CSelf41[一時項目表示X] Y:CSelf42[一時項目表示Y] / 5(3)ﾌﾚｰﾑ /
　　　　　　　　　ﾊﾟﾀｰﾝ 1 / 透同値 / 表示形式:同値 / 角同値 / 拡同値 / ｶﾗｰ同値
|||||■ﾋﾟｸﾁｬ移動：CSelf21[一時ピクチャ番号] X:CSelf41[一時項目表示X] Y:CSelf42[一時項目表示Y] / 5(5)ﾌﾚｰﾑ /
　　　　　　　　　ﾊﾟﾀｰﾝ 1 / 透同値 / 表示形式:同値 / 角同値 / 拡同値 / ｶﾗｰ同値
|||||■
||||◇ループここまで◇◇
||||▼
||||▼
||||▼ ここで【内容】を表示
||||■変数操作: CSelf13[一時変数D] = CSelf24[上部欄横サイズ] - CSelf88[座標倍率X[x10]]
||||■条件分岐(変数): 【1】 Sys84:画面ｻｲｽﾞ(0=320x240,1=640x480,2=800x600他=-1 が 0 と同じ
||||-◇分岐：【1】 [ Sys84:画面ｻｲｽﾞ(0=320x240,1=640x480,2=800x600他=-1 が 0 と同じ ]の場合↓
|||||■変数操作: CSelf13[一時変数D] *= 2 + 0
|||||■
||||◇分岐終了◇
||||▼ 購入の文字＋購入用カーソル
||||■文字列操作：CSelf6[メイン表示用] = "\f[\cself[19]]購入"
||||■変数操作: CSelf21[一時ピクチャ番号] = CSelf20[基本ピクチャ番号] + 4
||||■ﾋﾟｸﾁｬ[ﾃﾞｨﾚｲ内容ﾘｾｯﾄ]：CSelf21[一時ピクチャ番号]
||||■ﾋﾟｸﾁｬ表示：CSelf21[一時ピクチャ番号] [中心]文字列[\cself[6]] X:CSelf41[一時項目表示X] Y:CSelf42[一時項目表示Y]/
　　　　　　　　 0(0)ﾌﾚｰﾑ / ﾊﾟﾀｰﾝ 1 / 透 255 / 通常 / 角 0 / 拡 100％ / ｶﾗｰ R[100] G[100] B[100]
||||■条件分岐(変数): 【1】 CSelf0[処理モード] が 0 と同じ
||||-◇分岐：【1】 [ CSelf0[処理モード] が 0 と同じ ]の場合↓
|||||■条件分岐(変数): 【1】 CSelf1[[2]カーソル位置] が -11 と同じ
|||||-◇分岐：【1】 [ CSelf1[[2]カーソル位置] が -11 と同じ ]の場合↓
||||||■ﾋﾟｸﾁｬ移動：CSelf21[一時ピクチャ番号] X:CSelf41[一時項目表示X] Y:CSelf42[一時項目表示Y] /
　　　　　　　　　 0(0)ﾌﾚｰﾑ / ﾊﾟﾀｰﾝ 1 / 透 128 / 通常 / 角 0 / 拡 100％ / ｶﾗｰ R[100] G[100] B[100]
||||||■
|||||◇分岐終了◇
|||||■
||||◇分岐終了◇
||||■変数操作: CSelf12[一時変数C] = CSelf19[基本フォントサイズ] / 2
||||■変数操作: CSelf12[一時変数C] += CSelf89[座標倍率Y[x10]] / 2
||||■ピクチャエフェクト：CSelf21[一時ピクチャ番号] [描画座標ｼﾌﾄ(最終値)]
　　　　　　　　　　　　　Xｼﾌﾄ CSelf46[上部欄 [購入]シフト量] / Yｼﾌﾄ CSelf12[一時変数C] (0)ﾌﾚｰﾑ
||||▼ カーソル
||||■変数操作: CSelf21[一時ピクチャ番号] = CSelf20[基本ピクチャ番号] + 2
||||■ﾋﾟｸﾁｬ[ﾃﾞｨﾚｲ内容ﾘｾｯﾄ]：CSelf21[一時ピクチャ番号]
||||■ﾋﾟｸﾁｬ表示：CSelf21[一時ピクチャ番号] [中心]ｳｨﾝﾄﾞｳ(CSelf9[カーソル画像ファイル])
　　　　　　　　ｻｲｽﾞ[CSelf48[上部欄カーソル横サイズ],CSelf19[基本フォントサイズ]]
　　　　　　　　 X:CSelf41[一時項目表示X] Y:CSelf42[一時項目表示Y] / 0(0)ﾌﾚｰﾑ /
　　　　　　　　ﾊﾟﾀｰﾝ 1 / 透 0 / 加算 / 角 0 / 拡 100％ / ｶﾗｰ R[100] G[100] B[100]
||||■ピクチャエフェクト：CSelf21[一時ピクチャ番号] [描画座標ｼﾌﾄ(最終値)]
　　　　　　　　　　　　　Xｼﾌﾄ CSelf46[上部欄 [購入]シフト量] / Yｼﾌﾄ CSelf12[一時変数C] (0)ﾌﾚｰﾑ
||||▼
||||▼ 売却の文字＋売却用カーソル
||||■文字列操作：CSelf6[メイン表示用] = "\f[\cself[19]]売却"
||||■変数操作: CSelf21[一時ピクチャ番号] = CSelf20[基本ピクチャ番号] + 5
||||■ﾋﾟｸﾁｬ[ﾃﾞｨﾚｲ内容ﾘｾｯﾄ]：CSelf21[一時ピクチャ番号]
||||■ﾋﾟｸﾁｬ表示：CSelf21[一時ピクチャ番号] [中心]文字列[\cself[6]] X:CSelf41[一時項目表示X] Y:CSelf42[一時項目表示Y]/
　　　　　　　　 0(0)ﾌﾚｰﾑ / ﾊﾟﾀｰﾝ 1 / 透 255 / 通常 / 角 0 / 拡 100％ / ｶﾗｰ R[100] G[100] B[100]
||||■条件分岐(変数): 【1】 CSelf0[処理モード] が 0 と同じ
||||-◇分岐：【1】 [ CSelf0[処理モード] が 0 と同じ ]の場合↓
|||||■条件分岐(変数): 【1】 CSelf1[[2]カーソル位置] が -10 と同じ
|||||-◇分岐：【1】 [ CSelf1[[2]カーソル位置] が -10 と同じ ]の場合↓
||||||■ﾋﾟｸﾁｬ移動：CSelf21[一時ピクチャ番号] X:CSelf41[一時項目表示X] Y:CSelf42[一時項目表示Y] / 0(0)ﾌﾚｰﾑ /
　　　　　　　　　ﾊﾟﾀｰﾝ 1 / 透 128 / 通常 / 角 0 / 拡 100％ / ｶﾗｰ R[100] G[100] B[100]
||||||■
|||||◇分岐終了◇
|||||■
||||◇分岐終了◇
||||■変数操作: CSelf12[一時変数C] = CSelf19[基本フォントサイズ] / 2
||||■変数操作: CSelf12[一時変数C] += CSelf89[座標倍率Y[x10]] / 2
||||■ピクチャエフェクト：CSelf21[一時ピクチャ番号] [描画座標ｼﾌﾄ(最終値)]
　　　　　　　　　　　　　Xｼﾌﾄ CSelf47[上部欄 [売却]シフト量] / Yｼﾌﾄ CSelf12[一時変数C] (0)ﾌﾚｰﾑ
||||▼ カーソル
||||■変数操作: CSelf21[一時ピクチャ番号] = CSelf20[基本ピクチャ番号] + 3
||||■ﾋﾟｸﾁｬ[ﾃﾞｨﾚｲ内容ﾘｾｯﾄ]：CSelf21[一時ピクチャ番号]
||||■ﾋﾟｸﾁｬ表示：CSelf21[一時ピクチャ番号] [中心]ｳｨﾝﾄﾞｳ(CSelf9[カーソル画像ファイル])
　　　　　　　　ｻｲｽﾞ[CSelf48[上部欄カーソル横サイズ],CSelf19[基本フォントサイズ]]
　　　　　　　　 X:CSelf41[一時項目表示X] Y:CSelf42[一時項目表示Y] / 0(0)ﾌﾚｰﾑ /
　　　　　　　　ﾊﾟﾀｰﾝ 1 / 透 0 / 加算 / 角 0 / 拡 100％ / ｶﾗｰ R[100] G[100] B[100]
||||■ピクチャエフェクト：CSelf21[一時ピクチャ番号] [描画座標ｼﾌﾄ(最終値)]
　　　　　　　　　　　　　Xｼﾌﾄ CSelf47[上部欄 [売却]シフト量] / Yｼﾌﾄ CSelf12[一時変数C] (0)ﾌﾚｰﾑ
||||■
|||◇ループここまで◇◇
|||▼
|||■回数付きループ [ CSelf57[初期表示？(1=YES)] ]回
||||▼ ここで表示エフェクト（「移動」コマンドで実現している）
||||■変数操作: CSelf21[一時ピクチャ番号] = CSelf20[基本ピクチャ番号] + 1
||||■変数操作: CSelf26[一時ピクチャ2] = CSelf21[一時ピクチャ番号] + 5
||||▼ 初期位置をシフト
||||■変数操作: CSelf44[一時項目表示X2] = CSelf22[上部欄表示X] - CSelf24[上部欄横サイズ]
||||■変数操作: CSelf45[一時項目表示Y2] = CSelf42[一時項目表示Y] + 0
||||■ﾋﾟｸﾁｬ[ﾃﾞｨﾚｲ内容ﾘｾｯﾄ]：CSelf21[一時ピクチャ番号] ～ CSelf26[一時ピクチャ2]
||||■ﾋﾟｸﾁｬ移動：CSelf21[一時ピクチャ番号]～CSelf26[一時ピクチャ2]X:CSelf44[一時項目表示X2]Y:CSelf45[一時項目表示Y2]/
　　　　　　　　 0(0)ﾌﾚｰﾑ / ﾊﾟﾀｰﾝ 1 / 透同値 / 表示形式:同値 / 角 0 / 拡同値 / ｶﾗｰ R[100] G[100] B[100]
||||▼ 慣性移動
||||■ﾋﾟｸﾁｬ移動：CSelf21[一時ピクチャ番号]～CSelf26[一時ピクチャ2] X:CSelf41[一時項目表示X] Y:CSelf42[一時項目表示Y]/
　　　　　　　　 5(0)ﾌﾚｰﾑ / ﾊﾟﾀｰﾝ 1 / 透同値 / 表示形式:同値 / 角 0 / 拡同値 / ｶﾗｰ R[100] G[100] B[100]
||||■ﾋﾟｸﾁｬ移動：CSelf21[一時ピクチャ番号]～CSelf26[一時ピクチャ2] X:CSelf41[一時項目表示X] Y:CSelf42[一時項目表示Y]/
　　　　　　　　 5(3)ﾌﾚｰﾑ / ﾊﾟﾀｰﾝ 1 / 透同値 / 表示形式:同値 / 角同値 / 拡同値 / ｶﾗｰ R[100] G[100] B[100]
||||■ﾋﾟｸﾁｬ移動：CSelf21[一時ピクチャ番号]～CSelf26[一時ピクチャ2] X:CSelf41[一時項目表示X] Y:CSelf42[一時項目表示Y]/
　　　　　　　　 5(5)ﾌﾚｰﾑ / ﾊﾟﾀｰﾝ 1 / 透同値 / 表示形式:同値 / 角同値 / 拡同値 / ｶﾗｰ R[100] G[100] B[100]
||||■
|||◇ループここまで◇◇
|||▼ 表示処理ここまで
|||■
||◇ループここまで◇◇
||▼
||■回数付きループ [ 1 ]回
|||■チェックポイント■■■■■■■■■■■■■■■■■■■■■■■■
|||▼ お金欄を表示
|||■変数操作: CSelf41[一時項目表示X] = CSelf30[お金欄X] + 0
|||■変数操作: CSelf42[一時項目表示Y] = CSelf31[お金欄Y] + 0
|||■変数操作: CSelf44[一時項目表示X2] = CSelf30[お金欄X] - CSelf32[お金欄横サイズ]
|||■変数操作: CSelf45[一時項目表示Y2] = CSelf42[一時項目表示Y] + 0
|||■回数付きループ [ CSelf57[初期表示？(1=YES)] ]回
||||■変数操作: CSelf21[一時ピクチャ番号] = CSelf20[基本ピクチャ番号] + 10
||||■ﾋﾟｸﾁｬ[ﾃﾞｨﾚｲ内容ﾘｾｯﾄ]：CSelf21[一時ピクチャ番号]
||||■ﾋﾟｸﾁｬ表示：CSelf21[一時ピクチャ番号] [左上]ｳｨﾝﾄﾞｳ(CSelf8[ウィンドウ画像ファイル])
　　　　　　　　ｻｲｽﾞ[CSelf32[お金欄横サイズ],CSelf33[お金欄縦サイズ]] X:CSelf30[お金欄X] Y:CSelf31[お金欄Y] /
　　　　　　　　 0(0)ﾌﾚｰﾑ / ﾊﾟﾀｰﾝ 1 / 透 255 / 通常 / 角 0 / 拡 100％ / ｶﾗｰ R[100] G[100] B[100]
||||■回数付きループ [ 1 ]回
|||||▼ ここで表示エフェクト（「移動」コマンドで実現している）
|||||▼ 初期位置をシフト
|||||■ﾋﾟｸﾁｬ[ﾃﾞｨﾚｲ内容ﾘｾｯﾄ]：CSelf21[一時ピクチャ番号]
|||||■ﾋﾟｸﾁｬ移動：CSelf21[一時ピクチャ番号] X:CSelf44[一時項目表示X2] Y:CSelf45[一時項目表示Y2] / 0(0)ﾌﾚｰﾑ /
　　　　　　　　　ﾊﾟﾀｰﾝ 1 / 透同値 / 表示形式:同値 / 角同値 / 拡同値 / ｶﾗｰ同値
|||||▼ 慣性移動
|||||■ﾋﾟｸﾁｬ移動：CSelf21[一時ピクチャ番号] X:CSelf41[一時項目表示X] Y:CSelf42[一時項目表示Y] / 5(0)ﾌﾚｰﾑ /
　　　　　　　　　ﾊﾟﾀｰﾝ 1 / 透同値 / 表示形式:同値 / 角同値 / 拡同値 / ｶﾗｰ同値
|||||■ﾋﾟｸﾁｬ移動：CSelf21[一時ピクチャ番号] X:CSelf41[一時項目表示X] Y:CSelf42[一時項目表示Y] / 5(3)ﾌﾚｰﾑ /
　　　　　　　　　ﾊﾟﾀｰﾝ 1 / 透同値 / 表示形式:同値 / 角同値 / 拡同値 / ｶﾗｰ同値
|||||■ﾋﾟｸﾁｬ移動：CSelf21[一時ピクチャ番号] X:CSelf41[一時項目表示X] Y:CSelf42[一時項目表示Y] / 5(5)ﾌﾚｰﾑ /
　　　　　　　　　ﾊﾟﾀｰﾝ 1 / 透同値 / 表示形式:同値 / 角同値 / 拡同値 / ｶﾗｰ同値
|||||■
||||◇ループここまで◇◇
||||■
|||◇ループここまで◇◇
|||▼ ここで【内容】を表示
|||■変数操作: CSelf13[一時変数D] = CSelf32[お金欄横サイズ] - CSelf88[座標倍率X[x10]]
|||■条件分岐(変数): 【1】 Sys84:画面ｻｲｽﾞ(0=320x240,1=640x480,2=800x600他=-1 が 0 と同じ
|||-◇分岐：【1】 [ Sys84:画面ｻｲｽﾞ(0=320x240,1=640x480,2=800x600他=-1 が 0 と同じ ]の場合↓
||||■変数操作: CSelf13[一時変数D] *= 2 + 0
||||■
|||◇分岐終了◇
|||▼
|||■DB読込(ﾕｰｻﾞ)： CSelf7[一時文字列B] = ﾕｰｻﾞDB[ 用語設定 : 0 : 18 ] (15 : 用語基本設定 : [ｽﾃｰﾀｽ]お金の単位)
|||■文字列操作：CSelf6[メイン表示用] =
　　　　　　　　 "\f[\cself[18]]所持金\ax[\cself[13]]\n<R>\f[\cself[19]]\cself[95]\f[\cself[18]] \cself[7]"
|||■条件分岐(文字): 【1】 CSelf7[一時文字列B]が "枚" と同じ
|||-◇分岐：【1】 [ CSelf7[一時文字列B] "枚" と同じ ]の場合↓
||||■文字列操作：CSelf6[メイン表示用] =<から文字列を置換> "所持金" → "所持メダル"
||||■
|||◇分岐終了◇
|||■変数操作: CSelf21[一時ピクチャ番号] = CSelf20[基本ピクチャ番号] + 11
|||■ﾋﾟｸﾁｬ[ﾃﾞｨﾚｲ内容ﾘｾｯﾄ]：CSelf21[一時ピクチャ番号]
|||■ﾋﾟｸﾁｬ表示：CSelf21[一時ピクチャ番号] [左上]文字列[\cself[6]] X:CSelf41[一時項目表示X] Y:CSelf42[一時項目表示Y] /
　　　　　　　　0(0)ﾌﾚｰﾑ / ﾊﾟﾀｰﾝ 1 / 透 255 / 通常 / 角 0 / 拡 100％ / ｶﾗｰ R[100] G[100] B[100]
|||■変数操作: CSelf12[一時変数C] = CSelf88[座標倍率X[x10]] / 2
|||■ピクチャエフェクト：CSelf21[一時ピクチャ番号] [描画座標ｼﾌﾄ(最終値)]
　　　　　　　　　　　　 Xｼﾌﾄ CSelf12[一時変数C] / Yｼﾌﾄ CSelf12[一時変数C] (0)ﾌﾚｰﾑ
|||■回数付きループ [ CSelf57[初期表示？(1=YES)] ]回
||||▼ ここで表示エフェクト（「移動」コマンドで実現している）
||||▼ 初期位置をシフト
||||■変数操作: CSelf44[一時項目表示X2] = CSelf30[お金欄X] - CSelf32[お金欄横サイズ]
||||■変数操作: CSelf45[一時項目表示Y2] = CSelf42[一時項目表示Y] + 0
||||■ﾋﾟｸﾁｬ[ﾃﾞｨﾚｲ内容ﾘｾｯﾄ]：CSelf21[一時ピクチャ番号]
||||■ﾋﾟｸﾁｬ移動：CSelf21[一時ピクチャ番号] X:CSelf44[一時項目表示X2] Y:CSelf45[一時項目表示Y2] / 0(0)ﾌﾚｰﾑ /
　　　　　　　　ﾊﾟﾀｰﾝ 1 / 透 255 / 通常 / 角 0 / 拡同値 / ｶﾗｰ R[100] G[100] B[100]
||||▼ 慣性移動
||||■ﾋﾟｸﾁｬ移動：CSelf21[一時ピクチャ番号] X:CSelf41[一時項目表示X] Y:CSelf42[一時項目表示Y] / 5(0)ﾌﾚｰﾑ /
　　　　　　　　ﾊﾟﾀｰﾝ 1 / 透 255 / 通常 / 角 0 / 拡同値 / ｶﾗｰ R[100] G[100] B[100]
||||■ﾋﾟｸﾁｬ移動：CSelf21[一時ピクチャ番号] X:CSelf41[一時項目表示X] Y:CSelf42[一時項目表示Y] / 5(3)ﾌﾚｰﾑ /
　　　　　　　　ﾊﾟﾀｰﾝ 1 / 透 255 / 通常 / 角 0 / 拡同値 / ｶﾗｰ R[100] G[100] B[100]
||||■ﾋﾟｸﾁｬ移動：CSelf21[一時ピクチャ番号] X:CSelf41[一時項目表示X] Y:CSelf42[一時項目表示Y] / 5(5)ﾌﾚｰﾑ /
　　　　　　　　ﾊﾟﾀｰﾝ 1 / 透 255 / 通常 / 角 0 / 拡同値 / ｶﾗｰ R[100] G[100] B[100]
||||■
|||◇ループここまで◇◇
|||▼ 表示処理ここまで
|||■
||◇ループここまで◇◇
||■回数付きループ [ 1 ]回
|||■チェックポイント■■■■■■■■■■■■■■■■■■■■■■■■
|||▼ 所持数欄を表示
|||▼ 項目数が選択した場所より小さかった場合は調整
|||■DB読込(可変)： CSelf15[一時変数F] = 可変DB[ 基本ｼｽﾃﾑ用変数 : 17 : 数値 ] (18 : 万能ウィンドウ項目個数 : 0)
|||■変数操作: CSelf2[商品選択位置] 上限= CSelf15[一時変数F] - 1
|||■条件分岐(変数): 【1】 CSelf2[商品選択位置] が 0 以上
|||-◇分岐：【1】 [ CSelf2[商品選択位置] が 0 以上 ]の場合↓
||||■DB読込(可変)： CSelf97[所持数] = 可変DB[ 万能ｳｨﾝﾄﾞｳ一時DB : CSelf2[商品選択位置] : [ｵﾌﾟｼｮﾝ]予備数値A ](19:-:7)
||||■
|||-◇上記以外
||||■変数操作: CSelf97[所持数] = 0 + 0
||||■
|||◇分岐終了◇
|||■変数操作: CSelf41[一時項目表示X] = CSelf70[所持数欄表示X] + 0
|||■変数操作: CSelf42[一時項目表示Y] = CSelf71[所持数欄表示Y] + 0
|||■変数操作: CSelf44[一時項目表示X2] = CSelf70[所持数欄表示X] - CSelf72[所持数欄サイズX]
|||■変数操作: CSelf45[一時項目表示Y2] = CSelf42[一時項目表示Y] + 0
|||■変数操作: CSelf21[一時ピクチャ番号] = CSelf20[基本ピクチャ番号] + 20
|||■回数付きループ [ CSelf57[初期表示？(1=YES)] ]回
||||■ﾋﾟｸﾁｬ[ﾃﾞｨﾚｲ内容ﾘｾｯﾄ]：CSelf21[一時ピクチャ番号]
||||■ﾋﾟｸﾁｬ表示：CSelf21[一時ピクチャ番号] [左上]ｳｨﾝﾄﾞｳ(CSelf8[ウィンドウ画像ファイル])
　　　　　　　　ｻｲｽﾞ[CSelf72[所持数欄サイズX],CSelf73[所持数欄サイズY]]
　　　　　　　　 X:CSelf70[所持数欄表示X] Y:CSelf71[所持数欄表示Y] / 0(0)ﾌﾚｰﾑ /
　　　　　　　　ﾊﾟﾀｰﾝ 1 / 透 255 / 通常 / 角 0 / 拡 100％ / ｶﾗｰ R[100] G[100] B[100]
||||■回数付きループ [ 1 ]回
|||||▼ ここで表示エフェクト（「移動」コマンドで実現している）
|||||▼ 初期位置をシフト
|||||■ﾋﾟｸﾁｬ[ﾃﾞｨﾚｲ内容ﾘｾｯﾄ]：CSelf21[一時ピクチャ番号]
|||||■ﾋﾟｸﾁｬ移動：CSelf21[一時ピクチャ番号] X:CSelf44[一時項目表示X2] Y:CSelf45[一時項目表示Y2] / 0(0)ﾌﾚｰﾑ /
　　　　　　　　ﾊﾟﾀｰﾝ 1 / 透同値 / 表示形式:同値 / 角同値 / 拡同値 / ｶﾗｰ同値
|||||▼ 慣性移動
|||||■ﾋﾟｸﾁｬ移動：CSelf21[一時ピクチャ番号] X:CSelf41[一時項目表示X] Y:CSelf42[一時項目表示Y] / 5(0)ﾌﾚｰﾑ /
　　　　　　　　ﾊﾟﾀｰﾝ 1 / 透同値 / 表示形式:同値 / 角同値 / 拡同値 / ｶﾗｰ同値
|||||■ﾋﾟｸﾁｬ移動：CSelf21[一時ピクチャ番号] X:CSelf41[一時項目表示X] Y:CSelf42[一時項目表示Y] / 5(3)ﾌﾚｰﾑ /
　　　　　　　　ﾊﾟﾀｰﾝ 1 / 透同値 / 表示形式:同値 / 角同値 / 拡同値 / ｶﾗｰ同値
|||||■ﾋﾟｸﾁｬ移動：CSelf21[一時ピクチャ番号] X:CSelf41[一時項目表示X] Y:CSelf42[一時項目表示Y] / 5(5)ﾌﾚｰﾑ /
　　　　　　　　ﾊﾟﾀｰﾝ 1 / 透同値 / 表示形式:同値 / 角同値 / 拡同値 / ｶﾗｰ同値
|||||■
||||◇ループここまで◇◇
||||■
|||◇ループここまで◇◇
|||▼ ここで【内容】を表示
|||■変数操作: CSelf13[一時変数D] = CSelf32[お金欄横サイズ] - CSelf88[座標倍率X[x10]]
|||■条件分岐(変数): 【1】 Sys84:画面ｻｲｽﾞ(0=320x240,1=640x480,2=800x600他=-1 が 0 と同じ
|||-◇分岐：【1】 [ Sys84:画面ｻｲｽﾞ(0=320x240,1=640x480,2=800x600他=-1 が 0 と同じ ]の場合↓
||||■変数操作: CSelf13[一時変数D] *= 2 + 0
||||■
|||◇分岐終了◇
|||▼
|||■DB読込(ﾕｰｻﾞ)： CSelf7[一時文字列B] = ﾕｰｻﾞDB[ 用語設定 : 0 : 18 ] (15 : 用語基本設定 : [ｽﾃｰﾀｽ]お金の単位)
|||■【特】チェックポイント■■■■■■■■■■■■■■■■■■■■■■■■
|||▼ 対象の位置番号から所持数を得る処理追加
|||■変数操作: CSelf11[一時変数B] = 98765 + 0
|||■【特】チェックポイント■■■■■■■■■■■■■■■■■■■■■■■■
|||■文字列操作：CSelf6[メイン表示用] = "\f[\cself[19]]所持数\ax[\cself[13]]\n\ay[0]<R>\f[\cself[19]]\cself[97]"
|||■変数操作: CSelf21[一時ピクチャ番号] = CSelf20[基本ピクチャ番号] + 21
|||■ﾋﾟｸﾁｬ[ﾃﾞｨﾚｲ内容ﾘｾｯﾄ]：CSelf21[一時ピクチャ番号]
|||■ﾋﾟｸﾁｬ表示：CSelf21[一時ピクチャ番号] [左上]文字列[\cself[6]] X:CSelf41[一時項目表示X] Y:CSelf42[一時項目表示Y] /
　　　　　　　　0(0)ﾌﾚｰﾑ / ﾊﾟﾀｰﾝ 1 / 透 255 / 通常 / 角 0 / 拡 100％ / ｶﾗｰ R[100] G[100] B[100]
|||■変数操作: CSelf12[一時変数C] = CSelf88[座標倍率X[x10]] / 2
|||■変数操作: CSelf13[一時変数D] = CSelf89[座標倍率Y[x10]] / 2
|||■変数操作: CSelf13[一時変数D] += CSelf89[座標倍率Y[x10]] / 3
|||■ピクチャエフェクト：CSelf21[一時ピクチャ番号] [描画座標ｼﾌﾄ(最終値)]
　　　　　　　　　　　　 Xｼﾌﾄ CSelf12[一時変数C] / Yｼﾌﾄ CSelf13[一時変数D] (0)ﾌﾚｰﾑ
|||■回数付きループ [ CSelf57[初期表示？(1=YES)] ]回
||||▼ ここで表示エフェクト（「移動」コマンドで実現している）
||||▼ 初期位置をシフト
||||■変数操作: CSelf44[一時項目表示X2] = CSelf70[所持数欄表示X] - CSelf72[所持数欄サイズX]
||||■変数操作: CSelf45[一時項目表示Y2] = CSelf42[一時項目表示Y] + 0
||||■ﾋﾟｸﾁｬ[ﾃﾞｨﾚｲ内容ﾘｾｯﾄ]：CSelf21[一時ピクチャ番号]
||||■ﾋﾟｸﾁｬ移動：CSelf21[一時ピクチャ番号] X:CSelf44[一時項目表示X2] Y:CSelf45[一時項目表示Y2] / 0(0)ﾌﾚｰﾑ /
　　　　　　　　ﾊﾟﾀｰﾝ 1 / 透 255 / 通常 / 角 0 / 拡同値 / ｶﾗｰ R[100] G[100] B[100]
||||▼ 慣性移動
||||■ﾋﾟｸﾁｬ移動：CSelf21[一時ピクチャ番号] X:CSelf41[一時項目表示X] Y:CSelf42[一時項目表示Y] / 5(0)ﾌﾚｰﾑ /
　　　　　　　　ﾊﾟﾀｰﾝ 1 / 透 255 / 通常 / 角 0 / 拡同値 / ｶﾗｰ R[100] G[100] B[100]
||||■ﾋﾟｸﾁｬ移動：CSelf21[一時ピクチャ番号] X:CSelf41[一時項目表示X] Y:CSelf42[一時項目表示Y] / 5(3)ﾌﾚｰﾑ /
　　　　　　　　ﾊﾟﾀｰﾝ 1 / 透 255 / 通常 / 角 0 / 拡同値 / ｶﾗｰ R[100] G[100] B[100]
||||■ﾋﾟｸﾁｬ移動：CSelf21[一時ピクチャ番号] X:CSelf41[一時項目表示X] Y:CSelf42[一時項目表示Y] / 5(5)ﾌﾚｰﾑ /
　　　　　　　　ﾊﾟﾀｰﾝ 1 / 透 255 / 通常 / 角 0 / 拡同値 / ｶﾗｰ R[100] G[100] B[100]
||||■
|||◇ループここまで◇◇
|||▼ 表示処理ここまで
|||■
||◇ループここまで◇◇
||▼
||■回数付きループ [ 1 ]回
|||■チェックポイント■■■■■■■■■■■■■■■■■■■■■■■■
|||▼ 装備状況欄を表示
|||■文字列操作：CSelf7[一時文字列B] = ""
|||■条件分岐(変数): 【1】 CSelf2[商品選択位置] が 0 以上
|||-◇分岐：【1】 [ CSelf2[商品選択位置] が 0 以上 ]の場合↓
||||■DB読込(可変)： CSelf7[一時文字列B] = 可変DB[万能ｳｨﾝﾄﾞｳ一時DB:CSelf2[商品選択位置]:[ｵﾌﾟｼｮﾝ]予備文字列A](19:-:9)
||||■
|||◇分岐終了◇
|||■条件分岐(文字): 【1】 CSelf7[一時文字列B]が "" と同じ
|||-◇分岐：【1】 [ CSelf7[一時文字列B] "" と同じ ]の場合↓
||||▼ カラなら消去
||||■変数操作: CSelf21[一時ピクチャ番号] = CSelf20[基本ピクチャ番号] + 30
||||■ﾋﾟｸﾁｬ[ﾃﾞｨﾚｲ内容ﾘｾｯﾄ]：CSelf21[一時ピクチャ番号]
||||■ﾋﾟｸﾁｬ消去：CSelf21[一時ピクチャ番号] / 0(0)ﾌﾚｰﾑ
||||■変数操作: CSelf21[一時ピクチャ番号] = CSelf20[基本ピクチャ番号] + 31
||||■ﾋﾟｸﾁｬ[ﾃﾞｨﾚｲ内容ﾘｾｯﾄ]：CSelf21[一時ピクチャ番号]
||||■ﾋﾟｸﾁｬ消去：CSelf21[一時ピクチャ番号] / 0(0)ﾌﾚｰﾑ
||||■
|||-◇上記以外
||||▼ 表示する場合は瞬間表示
||||■変数操作: CSelf41[一時項目表示X] = CSelf50[装備状態欄X] + 0
||||■変数操作: CSelf42[一時項目表示Y] = CSelf51[装備状態欄Y] + 0
||||■変数操作: CSelf44[一時項目表示X2] = CSelf50[装備状態欄X] - CSelf52[装備状態欄横サイズ]
||||■変数操作: CSelf45[一時項目表示Y2] = CSelf42[一時項目表示Y] + 0
||||▼
||||■変数操作: CSelf21[一時ピクチャ番号] = CSelf20[基本ピクチャ番号] + 30
||||■ﾋﾟｸﾁｬ[ﾃﾞｨﾚｲ内容ﾘｾｯﾄ]：CSelf21[一時ピクチャ番号]
||||■ﾋﾟｸﾁｬ表示：CSelf21[一時ピクチャ番号] [左上]ｳｨﾝﾄﾞｳ(CSelf8[ウィンドウ画像ファイル])
　　　　　　　　ｻｲｽﾞ[CSelf52[装備状態欄横サイズ],CSelf53[装備状態欄縦サイズ]]
　　　　　　　　 X:CSelf50[装備状態欄X] Y:CSelf51[装備状態欄Y] / 0(0)ﾌﾚｰﾑ /
　　　　　　　　ﾊﾟﾀｰﾝ 1 / 透 255 / 通常 / 角 0 / 拡 100％ / ｶﾗｰ R[100] G[100] B[100]
||||■回数付きループ [ CSelf57[初期表示？(1=YES)] ]回
|||||■回数付きループ [ 0 ]回
||||||▼ ここで表示エフェクト（「移動」コマンドで実現している）
||||||▼ 初期位置をシフト
||||||■ﾋﾟｸﾁｬ[ﾃﾞｨﾚｲ内容ﾘｾｯﾄ]：CSelf21[一時ピクチャ番号]
||||||■ﾋﾟｸﾁｬ移動：CSelf21[一時ピクチャ番号] X:CSelf44[一時項目表示X2] Y:CSelf45[一時項目表示Y2] / 0(0)ﾌﾚｰﾑ /
　　　　　　　　　ﾊﾟﾀｰﾝ 1 / 透同値 / 表示形式:同値 / 角同値 / 拡同値 / ｶﾗｰ同値
||||||▼ 慣性移動
||||||■ﾋﾟｸﾁｬ移動：CSelf21[一時ピクチャ番号] X:CSelf41[一時項目表示X] Y:CSelf42[一時項目表示Y] / 5(0)ﾌﾚｰﾑ /
　　　　　　　　　ﾊﾟﾀｰﾝ 1 / 透同値 / 表示形式:同値 / 角同値 / 拡同値 / ｶﾗｰ同値
||||||■ﾋﾟｸﾁｬ移動：CSelf21[一時ピクチャ番号] X:CSelf41[一時項目表示X] Y:CSelf42[一時項目表示Y] / 5(3)ﾌﾚｰﾑ /
　　　　　　　　　ﾊﾟﾀｰﾝ 1 / 透同値 / 表示形式:同値 / 角同値 / 拡同値 / ｶﾗｰ同値
||||||■ﾋﾟｸﾁｬ移動：CSelf21[一時ピクチャ番号] X:CSelf41[一時項目表示X] Y:CSelf42[一時項目表示Y] / 5(5)ﾌﾚｰﾑ /
　　　　　　　　　ﾊﾟﾀｰﾝ 1 / 透同値 / 表示形式:同値 / 角同値 / 拡同値 / ｶﾗｰ同値
||||||■
|||||◇ループここまで◇◇
|||||■
||||◇ループここまで◇◇
||||▼ ここで【内容】を表示
||||■変数操作: CSelf13[一時変数D] = CSelf52[装備状態欄横サイズ] - CSelf88[座標倍率X[x10]]
||||■変数操作: CSelf13[一時変数D] -= CSelf88[座標倍率X[x10]] + 0
||||■条件分岐(変数): 【1】 Sys84:画面ｻｲｽﾞ(0=320x240,1=640x480,2=800x600他=-1 が 0 と同じ
||||-◇分岐：【1】 [ Sys84:画面ｻｲｽﾞ(0=320x240,1=640x480,2=800x600他=-1 が 0 と同じ ]の場合↓
|||||■変数操作: CSelf13[一時変数D] *= 2 + 0
|||||■
||||◇分岐終了◇
||||▼ 装備状況
||||■文字列操作：CSelf6[メイン表示用] = "\f[\cself[18]]\cself[7]"
||||■変数操作: CSelf21[一時ピクチャ番号] = CSelf20[基本ピクチャ番号] + 31
||||■ﾋﾟｸﾁｬ[ﾃﾞｨﾚｲ内容ﾘｾｯﾄ]：CSelf21[一時ピクチャ番号]
||||■ﾋﾟｸﾁｬ表示：CSelf21[一時ピクチャ番号] [左上]文字列[\cself[6]] X:CSelf41[一時項目表示X] Y:CSelf42[一時項目表示Y]/
　　　　　　　　 0(0)ﾌﾚｰﾑ / ﾊﾟﾀｰﾝ 1 / 透 255 / 通常 / 角 0 / 拡 100％ / ｶﾗｰ R[100] G[100] B[100]
||||■変数操作: CSelf12[一時変数C] = CSelf88[座標倍率X[x10]] / 1
||||■変数操作: CSelf13[一時変数D] = CSelf89[座標倍率Y[x10]] / 1
||||■ピクチャエフェクト：CSelf21[一時ピクチャ番号] [描画座標ｼﾌﾄ(最終値)]
　　　　　　　　　　　　　Xｼﾌﾄ CSelf12[一時変数C] / Yｼﾌﾄ CSelf13[一時変数D] (0)ﾌﾚｰﾑ
||||▼
||||■回数付きループ [ CSelf57[初期表示？(1=YES)] ]回
|||||▼ ここで表示エフェクト（「移動」コマンドで実現している）
|||||▼ 初期位置をシフト
|||||■変数操作: CSelf44[一時項目表示X2] = CSelf50[装備状態欄X] - CSelf52[装備状態欄横サイズ]
|||||■変数操作: CSelf45[一時項目表示Y2] = CSelf42[一時項目表示Y] + 0
|||||■ﾋﾟｸﾁｬ[ﾃﾞｨﾚｲ内容ﾘｾｯﾄ]：CSelf21[一時ピクチャ番号]
|||||■ﾋﾟｸﾁｬ移動：CSelf21[一時ピクチャ番号] X:CSelf44[一時項目表示X2] Y:CSelf45[一時項目表示Y2] / 0(0)ﾌﾚｰﾑ /
　　　　　　　　　ﾊﾟﾀｰﾝ 1 / 透 255 / 通常 / 角 0 / 拡同値 / ｶﾗｰ R[100] G[100] B[100]
|||||▼ 慣性移動
|||||■ﾋﾟｸﾁｬ移動：CSelf21[一時ピクチャ番号] X:CSelf41[一時項目表示X] Y:CSelf42[一時項目表示Y] / 5(0)ﾌﾚｰﾑ /
　　　　　　　　　ﾊﾟﾀｰﾝ 1 / 透 255 / 通常 / 角 0 / 拡同値 / ｶﾗｰ R[100] G[100] B[100]
|||||■ﾋﾟｸﾁｬ移動：CSelf21[一時ピクチャ番号] X:CSelf41[一時項目表示X] Y:CSelf42[一時項目表示Y] / 5(3)ﾌﾚｰﾑ /
　　　　　　　　　ﾊﾟﾀｰﾝ 1 / 透 255 / 通常 / 角 0 / 拡同値 / ｶﾗｰ R[100] G[100] B[100]
|||||■ﾋﾟｸﾁｬ移動：CSelf21[一時ピクチャ番号] X:CSelf41[一時項目表示X] Y:CSelf42[一時項目表示Y] / 5(5)ﾌﾚｰﾑ /
　　　　　　　　　ﾊﾟﾀｰﾝ 1 / 透 255 / 通常 / 角 0 / 拡同値 / ｶﾗｰ R[100] G[100] B[100]
|||||■
||||◇ループここまで◇◇
||||■
|||◇分岐終了◇
|||▼ 表示処理ここまで
|||■
||◇ループここまで◇◇
||■イベント処理中断
||■
|◇分岐終了◇
|■
◇分岐終了◇
■条件分岐(変数): 【1】 CSelf0[処理モード] が 2 と同じ
-◇分岐：【1】 [ CSelf0[処理モード] が 2 と同じ ]の場合↓
|▼ ■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■
|▼ 「カーソル表示」モード
|▼ ■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■
|■変数操作: CSelf21[一時ピクチャ番号] = CSelf20[基本ピクチャ番号] + 2
|■変数操作: CSelf26[一時ピクチャ2] = CSelf20[基本ピクチャ番号] + 3
|■条件分岐(変数): 【1】 CSelf1[[2]カーソル位置] が -2 と同じ
|-◇分岐：【1】 [ CSelf1[[2]カーソル位置] が -2 と同じ ]の場合↓
||▼ 「カーソル凍結」モード
||▼ 点滅停止＋少し暗くする
||■ピクチャエフェクト：CSelf21[一時ピクチャ番号] ～ CSelf26[一時ピクチャ2] [点滅A(明滅)] R0/G0/B0 明滅間隔(0)ﾌﾚｰﾑ
||■ﾋﾟｸﾁｬ移動：CSelf21[一時ピクチャ番号] ～ CSelf26[一時ピクチャ2] 相対X:0 Y:0 / 0(0)ﾌﾚｰﾑ /
　　　　　　　ﾊﾟﾀｰﾝ同値 / 透 180 / 表示形式:同値 / 角同値 / 拡同値 / ｶﾗｰ同値
||■イベント処理中断
||■
|◇分岐終了◇
|▼
|▼ 全カーソルの色を消去
|■ピクチャエフェクト：CSelf21[一時ピクチャ番号] ～ CSelf26[一時ピクチャ2] [色調整] R-100/G-100/B-100 (0)ﾌﾚｰﾑ
|■ピクチャエフェクト：CSelf21[一時ピクチャ番号] ～ CSelf26[一時ピクチャ2] [点滅A(明滅)] R0/G0/B0 明滅間隔(0)ﾌﾚｰﾑ
|▼
|▼ 指定カーソルの色だけ表示＋点滅
|■変数操作: CSelf21[一時ピクチャ番号] = CSelf20[基本ピクチャ番号] + 2
|■変数操作: CSelf21[一時ピクチャ番号] += CSelf1[[2]カーソル位置] + 0
|■ﾋﾟｸﾁｬ移動：CSelf21[一時ピクチャ番号] 相対X:0 Y:0 / 0(0)ﾌﾚｰﾑ /
　　　　　　　ﾊﾟﾀｰﾝ同値 / 透 255 / 表示形式:同値 / 角同値 / 拡同値 / ｶﾗｰ同値
|■ピクチャエフェクト：CSelf21[一時ピクチャ番号] [色調整] R0/G0/B0 (0)ﾌﾚｰﾑ
|■ピクチャエフェクト：CSelf21[一時ピクチャ番号] [点滅A(明滅)] R100/G100/B100 明滅間隔(15)ﾌﾚｰﾑ
|■イベント処理中断
|■
◇分岐終了◇
■

あとはお店の処理を使って、メダルと交換できるアイテムを登録して、お店の処理を実行するだけです。

▼設定例

【イベントコード表示】

■イベントの挿入[名]： ["【1】お店初期化"] <コモンEv 33>
■イベントの挿入[名]： ["【2】お店商品の追加"] <コモンEv 34> / 1:ｱｲﾃﾑ[A] / 2:魔力の水 / -1:<なし> / -1:<なし>
■イベントの挿入[名]： ["【2】お店商品の追加"] <コモンEv 34> / 2:武器[B] / -1:<なし> / 14:グレートソード / -1:<なし>
■イベントの挿入[名]： ["【2】お店商品の追加"] <コモンEv 34> / 3:防具[C] / -1:<なし> / -1:<なし> / 12:ナイトシールド
■イベントの挿入[名]： ["【3】お店処理実行"] <コモンEv 35> / 2:買いのみ

▲トップへ戻る▲

　　
■アイテム欄でメダルの所持数が確認できるようにする

アイテム「メダル袋」を持たせ、カジノの外にいる時にも、持っているメダルの枚数が分かるように設定します。

▼画面下のアイテム説明でメダルの所持枚数が表示されます。

カジノ内ではアイテム「メダル袋」を無くし、代わりにアイテム「所持金袋」を持たせて、
カジノ内では所持金が分かるように設定します。

ユーザーＤＢ[2:アイテム]に「メダル袋」と「所持金袋」を準備してください。

アイテム名	メダル袋	所持金袋
説明文	\v[1]枚のメダルが入っている。	\v[1]ゴールドのお金が入っている。
効果タイプ	効果のないアイテム	効果のないアイテム
販売価格	0	0

「所持金袋」はカジノに入る時に持たせ、カジノから出る時に失うようにします。

「メダル袋」はカジノから出る時に１枚以上のメダルがある時には持たせ、カジノに入る時に失うようにします。

カジノに入る時のイベントを以下のように変更してください。

カジノから出る時のイベントを以下のように変更してください。

【イベントコード表示】

■DB読込(可変)：このEvのSelf0 = 可変DB[ 6 : 0 : 0 ] (パーティー情報 : メイン設定 : 所持金)
■可変DB書込：DB[ 6 : 0 : 0 ] (パーティー情報 : メイン設定 : 所持金) = V1[メダル枚数]
■変数操作: V1[メダル枚数] = このEvのSelf0 + 0
■変数操作: このEvのSelf0 = 1015000018 + 0
■文字列操作：V[このEvのSelf0] = "ゴールド"
■イベントの挿入[名]： ["○アイテム増減"] <コモンEv 0> / 54:所持金袋 / -1 / 0:なし
■条件分岐(変数): 【1】 V1[メダル枚数] が 1 以上
-◇分岐：【1】 [ V1[メダル枚数] が 1 以上 ]の場合↓
|■イベントの挿入[名]： ["○アイテム増減"] <コモンEv 0> / 53:メダル袋 / 1 / 0:なし
|■
◇分岐終了◇

▲トップへ戻る▲

　　
■カジノ内でセーブが出来る場合

カジノ内でセーブが出来る場合、セーブしたものをロードすると、お金の単位が「ゴールド」に戻ってしまいます。

この問題を回避するためには、カジノ内にあるセーブが出来る全てのマップに以下のマップイベントを設定してください。

【イベントコード表示】

■マップイベント「お金の単位」

▼１ページ目
起動条件：並列実行
起動条件変数：なし

■変数操作: このEvのSelf0 = 1015000018 + 0
■文字列操作：V[このEvのSelf0] = "枚
■ループ開始
|■ウェイト：100000 フレーム
|■
◇ループここまで◇◇
■

▲トップへ戻る▲

YADOT-WOLFトップ　　気紛れな空間へ戻る　　メール
　